Limits of functions between metric spaces

Content created by Louis Wasserman and malarbol.

Created on 2025-08-18.
Last modified on 2025-08-18.

module metric-spaces.limits-of-functions-metric-spaces where
Imports 
open import elementary-number-theory.positive-rational-numbers

open import foundation.dependent-pair-types
open import foundation.existential-quantification
open import foundation.inhabited-subtypes
open import foundation.propositional-truncations
open import foundation.propositions
open import foundation.subtypes
open import foundation.universe-levels

open import metric-spaces.functions-metric-spaces
open import metric-spaces.metric-spaces

Idea

A function f between metric spaces X and Y has a limit y : Y at a point x : X if there exists a function m : ℚ⁺ → ℚ⁺ such that whenever x' is in an m ε-neighborhood of x, f x' is in an ε-neighborhood of y. In this case m is called a limit modulus of f at x.

Definitions

module _
  {l1 l2 l3 l4 : Level}
  (X : Metric-Space l1 l2)
  (Y : Metric-Space l3 l4)
  (f : type-function-Metric-Space X Y)
  (x : type-Metric-Space X)
  (y : type-Metric-Space Y)
  where

  is-modulus-of-point-limit-prop-function-Metric-Space :
    (ℚ⁺ → ℚ⁺) → Prop (l1 ⊔ l2 ⊔ l4)
  is-modulus-of-point-limit-prop-function-Metric-Space m =
    Π-Prop
      ( ℚ⁺)
      ( λ ε →
        Π-Prop
        ( type-Metric-Space X)
        ( λ x' →
          neighborhood-prop-Metric-Space X (m ε) x x' ⇒
          neighborhood-prop-Metric-Space Y ε y (f x')))

  is-modulus-of-point-limit-function-Metric-Space :
    (ℚ⁺ → ℚ⁺) → UU (l1 ⊔ l2 ⊔ l4)
  is-modulus-of-point-limit-function-Metric-Space m =
    type-Prop (is-modulus-of-point-limit-prop-function-Metric-Space m)

  is-point-limit-prop-function-Metric-Space : Prop (l1 ⊔ l2 ⊔ l4)
  is-point-limit-prop-function-Metric-Space =
    is-inhabited-subtype-Prop
      is-modulus-of-point-limit-prop-function-Metric-Space

  is-point-limit-function-Metric-Space : UU (l1 ⊔ l2 ⊔ l4)
  is-point-limit-function-Metric-Space =
    type-Prop is-point-limit-prop-function-Metric-Space

Recent changes