Baire space

Content created by Fredrik Bakke, Egbert Rijke, Jonathan Prieto-Cubides, Elif Uskuplu, Louis Wasserman and Victor Blanchi.

Created on 2022-06-30.
Last modified on 2025-10-25.

module set-theory.baire-space where
Imports 
open import elementary-number-theory.equality-natural-numbers
open import elementary-number-theory.natural-numbers

open import foundation.dependent-pair-types
open import foundation.double-negation-stable-equality
open import foundation.function-types
open import foundation.function-types-with-apartness-relations
open import foundation.lawveres-fixed-point-theorem
open import foundation.negation
open import foundation.propositional-truncations
open import foundation.sets
open import foundation.tight-apartness-relations
open import foundation.universe-levels

open import foundation-core.empty-types
open import foundation-core.identity-types

open import set-theory.cantors-diagonal-argument
open import set-theory.countable-sets
open import set-theory.uncountable-sets

Idea

The Baire space is the set of functions ℕ → ℕ. In other words, it is the set of infinite sequences of natural numbers.

Definition

baire-space : UU lzero
baire-space = ℕ → ℕ

Properties

The Baire space has a tight apartness relation

tight-apartness-relation-baire-space :
  Tight-Apartness-Relation lzero baire-space
tight-apartness-relation-baire-space =
  tight-apartness-relation-function-into-Type-With-Tight-Apartness
    ( ℕ)
    ( ℕ-Type-With-Tight-Apartness)

baire-space-Type-With-Tight-Apartness : Type-With-Tight-Apartness lzero lzero
baire-space-Type-With-Tight-Apartness =
  function-into-Type-With-Tight-Apartness ℕ ℕ-Type-With-Tight-Apartness

The Baire space has double negation stable equality

has-double-negation-stable-equality-baire-space :
  has-double-negation-stable-equality baire-space
has-double-negation-stable-equality-baire-space =
  has-double-negation-stable-equality-type-Type-With-Tight-Apartness
    baire-space-Type-With-Tight-Apartness

The Baire space is a set

is-set-baire-space : is-set baire-space
is-set-baire-space = is-set-function-type is-set-ℕ

baire-space-Set : Set lzero
baire-space-Set = (baire-space , is-set-baire-space)

The Baire space is uncountable

We give two proofs. The first proof uses that the successor function on the natural numbers has no fixed points and applies Lawvere’s fixed point theorem. The second proof uses that equality on the natural numbers is decidable, and applies Cantor’s diagonal argument.

abstract
  is-uncountable-baire-space : is-uncountable baire-space-Set
  is-uncountable-baire-space P =
    apply-universal-property-trunc-Prop
      ( is-directly-countable-is-countable baire-space-Set succ-ℕ P)
      ( empty-Prop)
      ( λ H →
        apply-universal-property-trunc-Prop
          ( fixed-point-theorem-Lawvere (pr2 H) succ-ℕ)
          ( empty-Prop)
          ( λ F →
            reductio-ad-absurdum (pr2 F) (has-no-fixed-points-succ-ℕ (pr1 F))))

abstract
  is-uncountable-baire-space' : is-uncountable baire-space-Set
  is-uncountable-baire-space' =
    is-uncountable-sequence-discrete-type-diagonal-argument-Cantor
      ( ℕ-Discrete-Type)
      ( 0)
      ( 1)
      ( is-nonzero-one-ℕ ∘ inv)

Recent changes